blob: 8b6a4676077e9ab6b272dbf78ff3c491f8a5ab5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Emil Velikov <emil.l.velikov@gmail.com>
# Maintainer: Eric Engestrom <aur@engestrom.ch>
# Contributor: Ben Widawsky <ben@bwidawsk.net>
# Contributor: Chad Versace <chad.versace@linux.intel.com>
pkgname=waffle
pkgver=1.7.0
pkgrel=2
pkgdesc='a library for choosing window system and OpenGL API at runtime'
arch=('x86_64')
url='https://waffle.freedesktop.org'
license=('BSD')
depends=('libx11' 'libxcb' 'libudev.so' 'libgl' 'libgles')
optdepends=('libegl: for gbm, surfaceless, x11_egl or wayland support'
'mesa: for gbm support'
'wayland: for wayland support')
# XXX: systemd is a bit of a hack, in particular:
# The Arch packaging splits the libudev.so in one package, with the build
# aka headers/pkg-config in another.
makedepends=('meson' 'xcb-proto' 'mesa' 'libxslt' 'docbook-xsl' 'cmake' 'systemd' 'wayland-protocols')
source=(https://mesa.pages.freedesktop.org/waffle/files/release/waffle-${pkgver}/waffle-${pkgver}.tar.xz{,.asc})
sha256sums=('69e42d15d08f63e7a54a8b8770295a6eb04dfd1c6f86c328b6039dbe7de28ef3'
'7a7e064395551ce20a694be7ecb4795effc3fd6f614943e50445469631677f6e')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D')
build() {
arch-meson "$pkgname-$pkgver" build \
--buildtype release \
-D build-manpages=true \
-D build-htmldocs=true \
-D build-examples=false
meson compile -C build
}
package() {
meson install -C build --destdir "$pkgdir"
install -m755 -d "$pkgdir/usr/share/licenses/$pkgname"
install -m644 "$pkgdir/usr/share/doc/waffle1/LICENSE.txt" \
"$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
}
|