blob: bc83137b01b0a6d984a1fb15153a2d0c82de5584 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: olalbns <olalbns@gmail.com>
pkgname=wallshift-git
_pkgname=WallShift
pkgver=r6.gff423e3
pkgrel=1
pkgdesc='GTK4 wallpaper manager with rotation and palette exports for Hyprland'
arch=('any')
url='https://github.com/olalbns/WallShift'
license=('MIT')
depends=('python' 'python-gobject' 'gtk4' 'python-pillow')
makedepends=('git' 'python-build' 'python-installer' 'python-setuptools' 'python-wheel')
optdepends=(
'awww: animated Wayland wallpaper backend (recommended)'
'swww: animated Wayland wallpaper backend'
'hyprpaper: Hyprland wallpaper backend'
)
provides=('wallshift')
conflicts=('wallshift')
source=("${_pkgname}::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
python -m build --wheel --no-isolation
}
package() {
cd "${srcdir}/${_pkgname}"
python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|