PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: Aleksandar Trifunović <akstrfn at gmail dot com>
# Contributor: Daichi Shinozaki <dsdseg at gmail dot com>

pkgname=wangle
pkgver=2018.10.08.00
pkgrel=1
pkgdesc="A full featured, high performance C++ futures implementation."
arch=('i686' 'x86_64')
url="https://github.com/facebook/wangle"
license=('Apache')
depends=('folly' 'boost-libs')
makedepends=('cmake' 'gflags' 'gtest' 'google-glog' 'boost')
source=("$url/archive/v${pkgver}.tar.gz")
sha256sums=('acdce41248119766af0258c526417f9a3c027184b0a2c715909e947463650774')

prepare() {
    cd "$pkgname-$pkgver/$pkgname"
    cmake -H. -Bbuild \
        -DCMAKE_C_FLAGS:STRING="${CFLAGS}" \
        -DCMAKE_CXX_FLAGS:STRING="${CXXFLAGS}" \
        -DCMAKE_EXE_LINKER_FLAGS:STRING="${LDFLAGS}" \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=Release
}

build() {
    cd "$pkgname-$pkgver/$pkgname"
    cmake --build build
}

check() {
    cd "$pkgname-$pkgver/$pkgname"
    cmake --build build -- test
}

package() {
    cd "$pkgname-$pkgver/$pkgname"
    cmake --build build -- DESTDIR=$pkgdir install
}