blob: d5a4ab314104b8553879b2440f3cfe4cbeed1d0a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Kyle Laker <kyle@laker.email>
pkgname=warpinator-git
pkgver=1.0.7.r3.g7a44020
pkgrel=1
pkgdesc="Share files across the LAN"
arch=('x86_64')
url="https://github.com/linuxmint/warp"
license=('GPL3')
depends=('gtk3' 'python-cryptography' 'python-gobject' 'python-grpcio'
'python-protobuf' 'python-pynacl' 'python-setproctitle' 'python-zeroconf'
'python-xapp' 'xapps' 'python-packaging')
makedepends=('git' 'meson' 'python-grpcio-tools' 'gobject-introspection' 'polkit')
optdepends=('ufw: Configure firewall rules')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/linuxmint/warp.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/warp"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/warp"
# Fix hard-coded libexec dir
sed -i 's/libexec/lib/g' \
"bin/${pkgname%-git}.in" \
install-scripts/meson_generate_and_install_protobuf_files.py
}
build() {
arch-meson warp build
meson compile -C build
}
package() {
DESTDIR="$pkgdir" meson install -C build
}
|