PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Kyle Laker <kyle@laker.email>
pkgname=warpinator-git
pkgver=1.1.2.r19.gb391632
pkgrel=2
pkgdesc="Share files across the LAN"
arch=('x86_64')
url="https://github.com/linuxmint/warpinator"
license=('GPL3')
depends=('gtk3' 'libnm' 'python-cryptography' 'python-gobject' 'python-grpcio'
         'python-netaddr' 'python-netifaces' 'python-protobuf' 'python-pynacl'
         'python-setproctitle' 'python-zeroconf' 'python-xapp' 'xapps')
makedepends=('git' 'meson' 'gobject-introspection')
optdepends=('polkit: Open a firewall port'
            'ufw: Configure firewall rules')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/linuxmint/warpinator.git')
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "$srcdir/${pkgname%-git}"

	# Fix hard-coded libexec dir
	sed -i 's/libexec/lib/g' "bin/${pkgname%-git}.in" "data/org.x.${pkgname%-git}.policy.in.in"
	sed -i 's/libexecdir="@libexecdir@"/libexecdir="@libdir@"/g' src/config.py.in
}

build() {
	arch-meson  "${pkgname%-git}" build -Dbundle-zeroconf=false
	meson compile -C build
}

package() {
	DESTDIR="$pkgdir" meson install -C build
}