blob: d8767f16b60d9cd245b85b3b308ad4286e992320 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: xuhcc <xuhcc at cryptolab dot net>
pkgname=wasabi-wallet-bin
_pkgname=wasabi-wallet
pkgver=2.0.2.0
_pkgver=2.0.2
pkgrel=1
pkgdesc="Open-source, non-custodial, privacy-focused Bitcoin wallet for desktop"
arch=('x86_64')
options=(!strip staticlibs)
url="https://wasabiwallet.io/"
license=('MIT')
depends=('curl' 'fontconfig' 'hicolor-icon-theme')
provides=('wasabi-wallet')
conflicts=('wasabi-wallet')
source=(
"https://github.com/zkSNACKs/WalletWasabi/releases/download/v${_pkgver}/Wasabi-${_pkgver}.deb"
"https://github.com/zkSNACKs/WalletWasabi/releases/download/v${_pkgver}/Wasabi-${_pkgver}.deb.asc"
"https://raw.githubusercontent.com/zkSNACKs/WalletWasabi/v${_pkgver}/LICENSE.md"
)
sha256sums=('4447fd834cf3d6592432a92ca42092654edc7f726366d62d43c3a8fe839bbe70'
'SKIP'
'cc774dc7850f7d097c1a5a987e2d7c89f8fa979e1f20dd8ac7905e6d1c5ec392')
# Run curl https://raw.githubusercontent.com/zkSNACKs/WalletWasabi/master/PGP.txt | gpg --import
validpgpkeys=('6FB3872B5D42292F59920797856348328949861E')
package() {
tar -xf "${srcdir}/data.tar.xz" -C "${pkgdir}"
chown -R root:root "${pkgdir}/usr/"
chmod -R go-w "${pkgdir}/usr/"
install -d -m755 "${pkgdir}/opt/"
cp -r "${pkgdir}/usr/local/bin/wasabiwallet/" "${pkgdir}/opt/${_pkgname}"
rm -r "${pkgdir}/usr/local/"
install -d -m755 "${pkgdir}/usr/bin/"
ln -s "/opt/${_pkgname}/wassabee" "${pkgdir}/usr/bin/wassabee"
ln -s "/opt/${_pkgname}/wassabee" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm644 "${srcdir}/LICENSE.md" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|