PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: tee < teeaur at duck dot com >
#pkgbase=wasmedge
_pkgname=WasmEdge
pkgname=(
    wasmedge-bin
    wasmedge-plugin-wasi-crypto
)
pkgver=0.13.2
pkgrel=2
pkgdesc="WasmEdge is a lightweight, high-performance, and extensible WebAssembly runtime"
arch=(x86_64 aarch64)
url="https://wasmedge.org"
_url="https://github.com/WasmEdge/WasmEdge"
license=(APACHE)
source=("$_url/raw/master/LICENSE")
source_x86_64=("$_url/releases/download/$pkgver/$_pkgname-$pkgver-manylinux2014_x86_64.tar.xz"
"$_url/releases/download/$pkgver/$_pkgname-plugin-wasi_crypto-$pkgver-manylinux2014_x86_64.tar.gz")
source_aarch64=("$_url/releases/download/$pkgver/$_pkgname-$pkgver-manylinux2014_aarch64.tar.xz")
sha256sums=('c71d239df91726fc519c6eb72d318ec65820627232b2f796219e87dcf35d0ab4')
sha256sums_x86_64=('5b7c3ec27ffc63d908fe396afe39b432365937af96776ab64629c500e831ab42'
                   '1449ee64da40f08b32c4072cd67abbebffea1e59c9326ec5688f0277ed6bc9ff')
sha256sums_aarch64=('7e71dc3a3cf454b5eaf052720f2b3fac71e0a9310b0ba76dfce2762c7036a904')

package_wasmedge-bin() {
    provides=(wasmedge)
    conflicts=(wasmedge)
    install -Dm644 LICENSE -t $pkgdir/usr/share/licenses/${_pkgname,,}/
    cd $_pkgname-$pkgver-Linux
    install -Dm755 bin/${_pkgname,,} -t $pkgdir/usr/bin/
    install -Dm755 bin/${_pkgname,,}c -t $pkgdir/usr/bin/
    install -Dm755 lib64/libwasmedge.so.0.0.3 -t $pkgdir/usr/lib/
    cp -d lib64/libwasmedge.so -t $pkgdir/usr/lib/
    cp -d lib64/libwasmedge.so.0 -t $pkgdir/usr/lib/
    install -D include/${_pkgname,,}/* -t $pkgdir/usr/include/
}

package_wasmedge-plugin-wasi-crypto() {
    pkgdesc='WasmEdge wasi crypto plugin'
    depends=(wasmedge)
    install -Dm755 libwasmedgePluginWasiCrypto.so -t $pkgdir/usr/lib/
}