summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: bf68f2801d36394f11dae88e0f162362e83c6ab8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
# Maintainer: Dario Ostuni <dario.ostuni@gmail.com>

pkgname=wasmtime
pkgver=0.16.0
pkgrel=1
pkgdesc="Standalone JIT-style runtime for WebAssembly, using Cranelift"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://github.com/bytecodealliance/wasmtime"
license=('APACHE2')
depends=()
makedepends=('cargo')
options=()
source=("${pkgname}-${pkgver}::git+https://github.com/bytecodealliance/wasmtime.git#tag=v${pkgver}")
sha384sums=('SKIP')

prepare() {
    cd "$srcdir/$pkgname-$pkgver"
    git submodule update --init --recursive
}

build() {
    cd "$srcdir/$pkgname-$pkgver"
    cargo build --release --bin wasmtime
    cargo build --release --manifest-path crates/c-api/Cargo.toml
}

package() {
    cd "$srcdir/$pkgname-$pkgver"
    install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
    install -Dm755 "target/release/lib${pkgname}.so" "$pkgdir/usr/lib/lib${pkgname}.so"
}