summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0d8a3dc76896cbf15e650c200bc263214517d737 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=wasmtime-git
pkgver=7.0.0.r173.g2d1dbb17a
pkgrel=1
pkgdesc="Standalone JIT-style runtime for WebAssembly"
arch=('i686' 'x86_64')
url="https://wasmtime.dev/"
license=('Apache')
depends=('gcc-libs')
makedepends=('git' 'rust')
provides=("wasmtime=$pkgver")
conflicts=('wasmtime')
source=("git+https://github.com/bytecodealliance/wasmtime.git")
sha256sums=('SKIP')


prepare() {
  cd "wasmtime"

  git submodule update --init --recursive

  if [ ! -f "Cargo.lock" ]; then
    cargo update
  fi
  cargo fetch
}

pkgver() {
  cd "wasmtime"

  _tag=$(git tag -l --sort -v:refname | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

check() {
  cd "wasmtime"

  #cargo test \
  #  --frozen
}

package() {
  cd "wasmtime"

  cargo install \
    --locked \
    --no-track \
    --root "$pkgdir/usr" \
    --path .

  install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/wasmtime"
}