blob: f77b5f87ddf7750eb05d5a93ba9fac0c0fbbc73b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
pkgname=watchman-bin
pkgver=2024.02.12.00
pkgrel=1
pkgdesc="An inotify-based file watching and job triggering command line utility"
url="https://facebook.github.io/watchman/"
arch=(x86_64)
license=(MIT)
depends=(openssl-1.1 gcc-libs)
makedepends=(patchelf python)
provides=("watchman=$pkgver")
conflicts=(watchman)
options=(!strip)
install=watchman.install
# https://github.com/facebook/watchman/releases
source=(
"https://github.com/facebook/watchman/releases/download/v$pkgver/watchman-v$pkgver-linux.zip"
"watchman-LICENSE::https://github.com/facebook/watchman/raw/v$pkgver/LICENSE"
)
b2sums=('59d8dce013a9d9be29380bb0c4263780b3301fa240fb7e1e18983394d8abda5c727b32882ffff700ff7baa18ea2a89ab1ebf228fa34a2f625c012c3a1b5ba104'
'b9c1c046dc0cd3c6bbf977f3e6d3f448a5fa26ac4d27aa3e2bf1c1a2f6bf97484a79f76c19bf5d5b3cf92400f951015a5036dfd8e183a2fdb0634ce992b12469')
prepare() {
cd watchman-v$pkgver-linux
python <<END
from pathlib import Path
data = Path("bin/watchman").read_bytes()
badpath = b"/usr/local/var/run/watchman\\x00"
goodpath = b"/run/./././././././watchman\\x00"
assert len(badpath) == len(goodpath)
data = data.replace(badpath, goodpath)
Path("bin/watchman").write_bytes(data)
END
patchelf \
--replace-needed {/usr/local/lib/,}libevent-2.1.so.7 \
--replace-needed {/usr/local/lib/,}libgflags.so.2.2 \
--replace-needed {/usr/local/lib/,}libglog.so.0 \
--replace-needed {/usr/local/lib/,}libsnappy.so.1 \
bin/* lib/*
patchelf --set-rpath /usr/lib/watchman bin/* lib/*
}
package() {
cd watchman-v$pkgver-linux
install -Dt "$pkgdir/usr/bin" bin/*
install -Dt "$pkgdir/usr/lib/watchman" lib/*
install -Dm644 /dev/stdin "$pkgdir/usr/lib/tmpfiles.d/watchman.conf" <<END
d /run/watchman 1777 root root
END
echo '{}' | install -Dm644 /dev/stdin "$pkgdir/etc/watchman.json.default"
install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/user/watchman.socket" <<END
[Unit]
Description=File watching service socket
Documentation=$url
[Socket]
ListenStream=/run/watchman/%u-state/sock
SocketMode=0600
DirectoryMode=0700
[Install]
WantedBy=sockets.target
END
install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/user/watchman.service" <<END
[Unit]
Description=File watching service
Documentation=$url
Requires=watchman.socket
[Service]
ExecStart=/usr/bin/watchman --foreground --inetd --logfile=-
StandardInput=socket
StandardOutput=journal
StandardError=inherit
[Install]
WantedBy=default.target
END
install -Dm644 ../watchman-LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set sw=2 et:
|