blob: 81f44ce46cac31a2c631e3bf81ccc0f219885722 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer: zoeyrae
# Contributor: zoeyrae <zoey.ronain at gmail dot com>
# Contributor: Envolution
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=waterfox-beta-bin
pkgver=6.7.5
_relver=6.7.5
pkgrel=1
pkgdesc="Beta/modern generation of customizable privacy-conscious web browser."
arch=('x86_64')
url="https://www.waterfox.net"
license=('MPL-2.0')
depends=('gtk3' 'libxt' 'startup-notification' 'mime-types' 'dbus-glib' 'ffmpeg'
'ttf-font' 'hicolor-icon-theme')
optdepends=('networkmanager: Location detection via available WiFi networks'
'libnotify: Notification integration'
'pulseaudio: Audio support'
'alsa-lib: Audio support'
'speech-dispatcher: Text-to-Speech'
'hunspell-en_US: Spell checking, American English')
provides=("waterfox=${pkgver}")
source=("https://cdn.waterfox.com/waterfox/releases/${_relver}/Linux_x86_64/waterfox-${_relver}.tar.bz2"
"waterfox.desktop")
package() {
# Create the necessary directories.
install -d "${pkgdir}"/{usr/{bin,share/applications},opt}
# Install the desktop files.
install -m644 "${srcdir}"/waterfox.desktop "${pkgdir}"/usr/share/applications/
# Copy the extracted directory to /opt/.
cp -r waterfox "${pkgdir}"/opt/waterfox
# Install icons
for i in 16 32 48 64 128; do
install -d "$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps"
ln -Ts /opt/waterfox/browser/chrome/icons/default/default$i.png \
"$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/waterfox.png"
done
# Add additional useful settings
install -Dm644 /dev/stdin "$pkgdir/opt/waterfox/browser/defaults/preferences/vendor.js" <<END
// Disable default browser checking
pref("browser.shell.checkDefaultBrowser", false);
// Use LANG environment variable to choose locale
pref("intl.locale.requested", "");
// Automatic installation of updates won't work on root, so disable this
pref("app.update.auto", false);
// Use system-provided dictionaries
pref("spellchecker.dictionary_path", "/usr/share/hunspell");
END
# Disable automatic updates and update notifications and allow only for manual update checking
install -Dm644 /dev/stdin "$pkgdir/opt/waterfox/distribution/policies.json" <<END
{
"policies": {
"AppAutoUpdate": false,
"ManualAppUpdateOnly": true
}
}
END
# Symlink the binary to /usr/bin/.
ln -s /opt/waterfox/waterfox "${pkgdir}"/usr/bin/waterfox
# Backward compatibility symlink
ln -s /opt/waterfox/waterfox "${pkgdir}"/usr/bin/waterfox-g
}
sha512sums=('86e933f5ad255a660581cfce0039ff7639b3018ad433bab5174f5a0a525b6c04dd736b103b62bb2f28551bc378131ac094b30792ed7e307d70d4bf778ae6463e'
'd0ff0445021b975d52eee7dac27dfdc0d170da07f8a8dc1676ba53387c2006f0598c163b36b07abdbb411cfb61bf52b8222fc5882bdfa8dfcd13d99cb44c92b6')
# vim:set ts=2 sw=2 et:
|