summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9b20234f529ffeb2d78c55bdd1c04bfbe6ef7b44 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: 0bCdian <diegoparranava@protonmail.com>
pkgname='waypaper-engine-git'
pkgver=3.0.0.r1.b7585ed
pkgrel=1
pkgdesc="A wallpaper setter GUI with playlist functionality for Wayland and X11 (git)"
arch=('x86_64')
url="https://github.com/0bCdian/Waypaper-Engine"
license=('GPL-3.0-or-later')
depends=('hicolor-icon-theme')
makedepends=('go' 'pnpm' 'nodejs' 'git')
conflicts=('waypaper-engine')
provides=('waypaper-engine')
optdepends=(
  'awww: animated wallpapers on Wayland'
  'hyprpaper: static image wallpapers on Hyprland'
  'mpvpaper: video wallpapers on wlroots compositors'
  'feh: static image wallpapers on X11'
  'wal-qt: HTML / WebEngine wallpaper backend'
  'xorg-xrandr: monitor detection on X11'
)
_archive="Waypaper-Engine"
source=("git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_archive"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
}

prepare() {
  cd "$_archive"
  make deps
}

build() {
  cd "$_archive"
  make electron
}

package() {
  cd "$_archive"
  make install-system DESTDIR="$pkgdir" INSTALL_PREFIX_SYSTEM=/usr \
    ICON_DIR="$pkgdir/usr/share/icons/hicolor/512x512/apps"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/waypaper-engine/LICENSE"
}