blob: 170098effd1014aef5d3b77492d310253fa16af2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Rich Baird <rich@rbaird.me>
pkgname=wayvnc-git
_pkgname=wayvnc
pkgver=0.9.1+31.ge12cb689f3
pkgrel=2
pkgdesc='VNC server for wlroots-based Wayland compositors'
arch=(x86_64 i686 aarch64 armv7h)
url=https://github.com/any1/wayvnc
license=(custom:ISC)
depends=(
ffmpeg
mesa
libxkbcommon
wayland
)
makedepends=(
git
meson
scdoc
)
source=(
"$_pkgname::git+$url"
"neatvnc::git+https://github.com/any1/neatvnc.git"
"aml::git+https://github.com/any1/aml.git"
)
sha512sums=('SKIP' 'SKIP' 'SKIP')
conflicts=(wayvnc)
provides=(wayvnc=${pkgver%+*})
pkgver() {
cd "$_pkgname"
git describe --tags --abbrev=10 | sed 's/^v//; s/-/+/; s/-/./'
}
prepare() {
# Create the subprojects directory for wayvnc
mkdir -p "$_pkgname/subprojects"
# Link neatvnc and aml into wayvnc's subprojects
# Note: The paths are relative to the link location
ln -s ../../neatvnc "$_pkgname/subprojects/neatvnc"
ln -s ../../aml "$_pkgname/subprojects/aml"
# Create the subprojects directory for neatvnc
mkdir -p "neatvnc/subprojects"
# Link aml into neatvnc's subprojects
ln -s ../../aml "neatvnc/subprojects/aml"
}
build() {
arch-meson "$_pkgname" build # --prefix /usr
ninja -C build
}
package() {
DESTDIR="$pkgdir" ninja -C build install
install -Dm 644 "$_pkgname/COPYING" -t "$pkgdir"/usr/share/licenses/$pkgname
}
|