PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: John Trengrove <john at weaviate dot-symbol io>
# Contributor: tee < teeaur at duck dot com >

pkgname=weaviate
pkgver=1.38.8
pkgrel=1
_commit=50767af
pkgdesc='An open source vector database written in Go'
arch=(x86_64 aarch64)
url='https://github.com/weaviate/weaviate'
license=(BSD-3-Clause)
depends=(glibc)
makedepends=(git go)
source=("$pkgname::git+$url#commit=${_commit}?signed"
        weaviate.default
        weaviate.service
        weaviate.sysusers
        weaviate.tmpfiles)
sha256sums=('b6103fc5c8ac9a62e2708594adee78512a53679ea97b33ae048950760e480513'
            'a375b1c55be48563ea3284a264352f1673c3f8e8f83bfd337c2ddfaeb532ce6d'
            '1507f4003ed6d3d5230cc9570e6f69c3be6177b52496b976f10a93519626b86a'
            'a644fc4eaa46e97381df09b5321e60a9ca1cfdac67277b8fe103fb4bd96d4fa0'
            '557f6c52ca3c4dc261a5ff11e4d998b9f66690c8ee2075450a2a225107b58f57')
validpgpkeys=(CFC67B5024BEB759BE2FADF262EADC233D625E3D) ## jeroiraz

prepare() {
    cd "$pkgname"
    export GOPATH="$srcdir"
    go mod download -modcacherw
    mkdir -p build
}

build() {
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
    
    cd "$pkgname"
    go build -o build ./cmd/weaviate-server/
}

package() {
    # binary
    install -Dm755 "$pkgname/build/weaviate-server" "${pkgdir}/usr/bin/weaviate"

    # user/group & owned directories
    install -Dm644 weaviate.sysusers "${pkgdir}/usr/lib/sysusers.d/weaviate.conf"
    install -Dm644 weaviate.tmpfiles "${pkgdir}/usr/lib/tmpfiles.d/weaviate.conf"

    # services & runtime
    install -Dm644 weaviate.service -t "${pkgdir}/usr/lib/systemd/system/"
    install -Dm644 weaviate.default "${pkgdir}/etc/default/weaviate"

    install -Dm644 "$pkgname/README.md" -t "${pkgdir}/usr/share/doc/${pkgname}/"

    # licenses
    install -Dm644 "$pkgname/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}