blob: 13bf4870d7135def1a676d6cb35e2c142f83774b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota.com>
# Contributor: spsf64 <at g m a i l dot com>
pkgname=webapp-manager
pkgver=1.1.5
pkgrel=3
pkgdesc="Run websites as if they were apps"
arch=('any')
url="https://github.com/linuxmint/webapp-manager"
license=('GPL')
depends=('python-beautifulsoup4' 'python-configobj' 'python-gobject' 'python-pillow'
'python-setproctitle' 'python-tldextract' 'dconf' 'xapp')
makedepends=('git')
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('05c88d7007d5de77d0dda37eb7772a80f72b0421f8140c73ffa457c841c5132b')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# Fix browser names
sed -i 's/brave-browser/brave/g' \
"usr/lib/${pkgname}/common.py"
sed -i 's/epiphany-browser/epiphany/g' \
"usr/lib/${pkgname}/common.py"
sed -i 's/"google-chrome"/"google-chrome-stable"/g' \
"usr/lib/${pkgname}/common.py"
sed -i 's/microsoft-edge/microsoft-edge-beta/g' \
"usr/lib/${pkgname}/common.py"
sed -i 's/"vivaldi"/"vivaldi-stable"/g' \
"usr/lib/${pkgname}/common.py"
# Fix license path
sed -i 's;common-licenses/GPL/licenses;common/GPL/license.txt;g' \
"usr/lib/${pkgname}/${pkgname}.py"
# Set version in About dialog
sed -i "s/__DEB_VERSION__/${pkgver}/g" \
"usr/lib/${pkgname}/${pkgname}.py"
}
build() {
cd "$srcdir/$pkgname-$pkgver"
make buildmo
}
package() {
cd "$srcdir/$pkgname-$pkgver"
cp -r etc usr "$pkgdir"
}
|