blob: ccae970e149ec5736833aa7d09460edc38cc64c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
_name=webcord
pkgname=${_name}-bin
pkgver=4.4.2
pkgrel=1
pkgdesc='A Discord and SpaceBar Electron-based client implemented without Discord API (binary release)'
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/SpacingBat3/WebCord"
license=('MIT')
provides=("${_name}")
conflicts=("${_name}")
options=('!strip' '!emptydirs')
_get_source() {
echo "${url}/releases/download/v${pkgver}/${_name}-${pkgver}-1.${1}.rpm"
}
source_x86_64=("$(_get_source x86_64)")
source_aarch64=("$(_get_source arm64)")
source_armv7h=("$(_get_source armv7hl)")
sha256sums_x86_64=('dd65c27d885a1fdc3e67289646b593031b68c0a1b295b608136eaa8543d8caa6')
sha256sums_aarch64=('ba8d80fc4d4099d148714abb29cb3a3f1b22da2264267638eecb822060799510')
sha256sums_armv7h=('ad0dafbc73e74d693649a1e9aca750dba08a0e8ace35477221654a69b21a9c75')
noextract=(
"${source_x86_64[0]##*/}"
"${source_aarch64[0]##*/}"
"${source_armv7h[0]##*/}"
)
package() {
local sname="source_${CARCH}"
bsdtar -xf "${!sname[0]##*/}" \
-C "${pkgdir}" \
--exclude="usr/lib/.build-id" \
--exclude="usr/bin" \
--exclude="usr/share/doc"
local bin="${pkgdir}/usr/bin"
install -dm755 "${bin}"
mv "${pkgdir}/usr/lib" "${pkgdir}/opt"
ln -s "/opt/${_name}/${_name}" "${bin}/${_name}"
}
|