PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer:  Dimitris Kiziridis <ragouel at outlook dot com>
# Contributor: sputnick <gilles *DOT* quenot *AT* gmail *DOT* com>
# Contributor: ianux <ianux@free.fr>

pkgname=weboob-git
pkgver=2.0.r315.g0f6bc340c
pkgrel=1
pkgdesc="Core library and modules for Web Outside of Browsers"
arch=(any)
url="https://weboob.org/"
license=('LGPL-3.0+')
depends=('python-lxml'
	     'python-cssselect'
	     'python-requests'
	     'python-dateutil'
	     'python-yaml'
	     'python-html2text'
	     'python-six'
	     'python-unidecode'
	     'python-pillow'
	     'python-babel'
	     'python-simplejson')
optdepends=('python-prettytable: CLI output formatting'
    		'python-feedparser: required by some modules')
makedepends=('python-setuptools' 'git')
replaces=('weboob-headless')
provides=('weboob-headless')
conflicts=('weboob-headless')
source=("git+https://git.weboob.org/weboob/weboob")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/weboob"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${srcdir}/weboob"
  python setup.py build
}

package() {
  cd "${srcdir}/weboob"
  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
}