PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: ewgsta <ewgst@proton.me>
pkgname=weeb-cli
pkgver=2.16.3
pkgrel=1
pkgdesc="No browser, no ads, no distractions. Just you and an unparalleled anime viewing experience."
arch=('any')
url="https://github.com/ewgsta/weeb-cli"
license=('GPL-3.0-only')
depends=(
    'python>=3.12'
    'python-typer'
    'python-rich'
    'python-questionary'
    'python-requests'
    'python-packaging'
    'python-beautifulsoup4'
    'python-lxml'
    'python-pycryptodome'
    'python-curl_cffi'
    'python-appdirs'
    'python-prompt_toolkit'
    'python-pyfiglet'
    'python-py7zr'
    'python-pypresence'
)
optdepends=(
    'mpv: for video playback'
    'aria2: for fast multi-connection downloads'
    'yt-dlp: for advanced stream support'
    'ffmpeg: for video processing and fallback downloads'
    'python-flask: for Torznab and RESTful API server modes'
    'python-flask-cors: for RESTful API CORS support'
    'python-yaml: for Torznab server configuration'
)
makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools')
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/${pkgname//-/_}-$pkgver.tar.gz")
sha256sums=('SKIP') 

build() {
    cd "$srcdir/${pkgname//-/_}-$pkgver"
    python -m build --wheel --no-isolation
}

package() {
    cd "$srcdir/${pkgname//-/_}-$pkgver"
    python -m installer --destdir="$pkgdir" dist/*.whl
}