PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: Nikos Toutountzoglou <nikos.toutou@protonmail.com>

pkgname=wg++
pkgver=5.1.5
pkgrel=3
pkgdesc="WebGrab+Plus is a multi-site incremental xmltv epg grabber"
arch=(any)
url="http://webgrabplus.com/"
license=(custom)
depends=(
	dotnet-runtime-8.0
	libxml2
	unzip
)
source=("${pkgname}-5.1.0.tar.gz::http://webgrabplus.com/sites/default/files/download/SW/V5.1.0/WebGrabPlus_V5.1_install.tar_0.gz"
	"${pkgname}-${pkgver}.tar.gz::http://webgrabplus.com/sites/default/files/download/SW/V${pkgver}/WebGrabPlus_V${pkgver}_beta_install.tar.gz"
	"http://webgrabplus.com/sites/default/files/download/ini/SiteIniPack_current.zip"
	'wgpp.sh')
sha256sums=('368b14be4b0ec724ac394b59b26c05ecff3cef2864572a8cca844d56e1ce6f0f'
            '8d9b7cdff826ae4bd8aa8f033bafcf5bea6525b3b6fbdebf724918b1ba788ad0'
            '8d93b5c52f0926a4cd6c3ef7533b288f62de7e6966114be0b95135682d52c5ea'
            '940392becb59c70f97c5ed1a1d49aab7d69386b5a4bb724bd48b8da39e40e1cc')

prepare() {
	# Rename folder
	mv .$pkgname $pkgname
	# Install latest SiteIniPack from 'http://webgrabplus.com/node/231'
	cp -r siteini.pack/* $pkgname/siteini.pack.update
	# Run install.sh script
	cd $pkgname
	./install.sh
	# Fix for 'No Internet' issue
	sed -i 's/guide\.xml/latest\.xml/g' WebGrab++.config.xml
}

package() {
	install -d "$pkgdir"/usr/share/$pkgname/{bin.net,doc,mdb,rex,siteini.pack,siteini.user}
	cp -r --no-preserve=mode,ownership "$srcdir"/$pkgname/{bin.net,doc,mdb,rex,siteini.pack} "$pkgdir"/usr/share/$pkgname
	install -Dm644 "$srcdir"/$pkgname/WebGrab++.config.example.xml "$pkgdir"/usr/share/$pkgname/WebGrab++.config.example.xml
	install -Dm644 "$srcdir"/$pkgname/WebGrab++.config.xml "$pkgdir"/usr/share/$pkgname/WebGrab++.config.xml
	install -Dm755 "$srcdir"/$pkgname/install.sh "$pkgdir"/usr/share/$pkgname/install.sh
	install -Dm755 "$srcdir"/$pkgname/run.net.sh "$pkgdir"/usr/share/$pkgname/run.net.sh
	install -Dm755 "$srcdir"/wgpp.sh "$pkgdir"/usr/bin/$pkgname
}