blob: 38170ff8427a471aa42f02f6b8b27165d6d7f0e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Akira Fukushima <h3.poteto@gmail.com>
pkgname=whalebird
pkgver=4.4.4
pkgrel=1
pkgdesc="An Electron based Mastodon, Pleroma and Misskey client"
arch=('x86_64')
url="https://whalebird.social"
license=('MIT')
depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libnghttp2' 'libxslt' 'minizip'
'nss' 're2' 'snappy' 'libnotify')
makedepends=('yarn' 'tar' 'nodejs>=14.15')
provides=('whalebird')
source=("https://github.com/h3poteto/whalebird-desktop/archive/refs/tags/$pkgver.tar.gz"
whalebird.desktop
electron-builder.yml)
md5sums=('dc5a052affddf99fe47cfdbe95352ec6'
'2cf7ef689d208d2fa41ce3622dce3545'
'68af72623ba3763c9a1ea440b72a253d')
prepare() {
cd "whalebird-desktop-${pkgver}"
rm -f electron-builder.json
}
build() {
cp electron-builder.yml "whalebird-desktop-${pkgver}"/electron-builder.yml
cd "whalebird-desktop-${pkgver}"
make build
yarn exec electron-builder --linux --dir --config electron-builder.yml
}
package() {
mkdir -p "${pkgdir}/usr/bin"
mkdir -p "${pkgdir}/usr/share"
mv "whalebird-desktop-${pkgver}/build/linux-unpacked" "${pkgdir}/usr/share/${pkgname}"
ln -sf "/usr/share/${pkgname}/whalebird" "${pkgdir}/usr/bin/whalebird"
for i in 16 32 128 256 512; do
install -Dm 644 "whalebird-desktop-${pkgver}/build/icons/icon.iconset/icon_${i}x${i}.png" \
"${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/whalebird.png"
done
install -Dm 644 "whalebird-desktop-${pkgver}/build/icons/icon.iconset/icon_32x32@2x.png" \
"${pkgdir}/usr/share/icons/hicolor/64x64/apps/whalebird.png"
install -Dm644 -t "${pkgdir}/usr/share/applications" whalebird.desktop
install -Dm 644 "whalebird-desktop-${pkgver}/LICENSE.txt" -t "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|