PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Caio Novais <caionov08 at gmail dot com>
# shellcheck shell=bash
# shellcheck disable=SC2034,SC2154
pkgname=whatsapp-for-linux
pkgver=1.0.8
pkgrel=1
pkgdesc="An unofficial WhatsApp linux client desktop application."
arch=('x86_64')
url="https://github.com/eneshecan/$pkgname"
license=('GPL')
depends=('gtkmm3' 'webkit2gtk')
makedepends=('cmake')
provides=("$pkgname")
source=("$pkgname-$pkgver.tar.gz::https://github.com/eneshecan/$pkgname/archive/v$pkgver.tar.gz")
sha1sums=('3f12c2909b1d60cc1c247e29f9f4b834c18c7494')

build() {
  cd "$srcdir/$pkgname-$pkgver" || exit
  mkdir -p build/release && cd build/release || exit
  cmake -DCMAKE_BUILD_TYPE=Release ../..
  make
}

package() {
  msg2 "Copying binary..."
  install -Dm755 "$srcdir/$pkgname-$pkgver/build/release/$pkgname" "$pkgdir/usr/bin/$pkgname"

  msg2 "Copying resources..."
  # .desktop
  install -Dm644 "$srcdir/$pkgname-$pkgver/resource/desktop/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"

  # Icons
  for i in 16x16 32x32 64x64 128x128 256x256; do
    install -Dm644 "$srcdir/$pkgname-$pkgver/resource/image/icons/hicolor/$i/apps/$pkgname.png" "$pkgdir/usr/share/icons/hicolor/$i/apps/$pkgname.png"
  done
}