blob: 9d7a327d40d49f2617f2b6980e14a45fd4ccfde8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Fredy García <frealgagu at gmail dot com>
pkgname=whatsapp-nativefier
pkgver=2.2134.10
pkgrel=1
pkgdesc="WhatsApp desktop built with nativefier (electron)"
arch=("armv7l" "i686" "x86_64")
url="https://web.${pkgname%-nativefier}.com"
license=("custom")
depends=("gtk3" "libxss" "nss")
optdepends=("libindicator-gtk3")
makedepends=("imagemagick" "nodejs-nativefier" "unzip")
source=(
"${pkgname}.png"
"${pkgname}.desktop"
"${pkgname}-inject.js"
)
sha256sums=(
"3899581abcfed9b40b7208bbbca8bdbfe3ae9655980dbf55f04dec9cb3309f27"
"bad0489ae519bc78afab3d226966691feede8bcedf58025af1b171215ae51423"
"f46bdc1adc9868d13b4f0809667cd5a9b1a6e5e47bc25b570f062d7072d0f942"
)
build() {
cd "${srcdir}"
nativefier \
--name "WhatsApp" \
--icon "${pkgname}.png" \
--width "800px" \
--height "600px" \
--user-agent "safari" \
--inject "${pkgname}-inject.js" \
--browserwindow-options '{ "webPreferences": { "spellcheck": true } }' \
--verbose \
--single-instance \
--tray \
"${url}"
}
package() {
install -dm755 "${pkgdir}/"{opt,usr/{bin,share/{applications,licenses/${pkgname}}}}
_folder=$(ls "${srcdir}" | grep "[Ww]hats[-]*[Aa]pp-linux-")
_binary=$(ls "${srcdir}/${_folder}" | grep "[Ww]hats[-]*[Aa]pp")
sed -i -e "/loglevel/d" "${srcdir}/${_folder}/resources/app/lib/preload.js"
cp -rL "${srcdir}/${_folder}" "${pkgdir}/opt/${pkgname}"
ln -s "/opt/${pkgname}/${_binary}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 "${pkgdir}/opt/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
for _size in "192x192" "128x128" "96x96" "64x64" "48x48" "32x32" "24x24" "22x22" "20x20" "16x16" "8x8"
do
install -dm755 "${pkgdir}/usr/share/icons/hicolor/${_size}/apps"
convert "${srcdir}/${pkgname}.png" -strip -resize "${_size}" "${pkgdir}/usr/share/icons/hicolor/${_size}/apps/${pkgname}.png"
done
}
|