blob: fed8b4f397b96312315dd15851bf4371bc6dc202 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Frederik "Freso" S. Olesen <archlinux@freso.dk>
# Contributor: Bastien Traverse <firstname at lastname dot email>
# Contributor: Samantha Baldwin <fuhsaz+git@cryptic.li>
# Contributor: Caleb Reach <jtxx000@gmail.com>
# Contributor: Felix Yan <felixonmars@gmail.com>
# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
# Contributor: Mantas Mikulėnas <grawity@gmail.com>
# Based on community/morituri and aur/morituri-git PKGBUILDs
pkgname=whipper-git
pkgver=0.9.1.dev138+g731453e
pkgrel=1
pkgdesc='A Unix CD ripper aiming for accuracy over speed -- forked from morituri'
arch=('any')
url='https://github.com/whipper-team/whipper'
license=('GPL3')
depends=(
'cdrdao' # for session, TOC, pregap, and ISRC extraction
'flac' # for reading flac files
'libcdio-paranoia' # for the actual ripping
'libsndfile' # for reading wav files
'python-discid' # for calculating MusicBrainz Disc IDs
'python-mutagen' # for metadata handling
'python-musicbrainzngs' # for metadata lookup
'python-gobject'
'python-pycdio' # for storing drive identification in config file
'python-ruamel-yaml' # for generating and reading logs
'python-setuptools' # for plugin support
'sox' # for track peak detection'
)
makedepends=(
'git' 'make'
'python-setuptools-scm' # for VCS(/SCM) versioning
'python-docutils' # for building man pages
)
optdepends=(
'python-pillow: for complete cover art support'
)
checkdepends=(
'python-twisted'
)
provides=("${pkgname%-git}" 'accuraterip-checksum')
conflicts=("${pkgname%-git}" 'accuraterip-checksum')
source=("git+$url.git#branch=develop")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname%-git}"
python3 setup.py --version
}
build() {
cd "$srcdir/${pkgname%-git}"
python3 setup.py build
cd man
make
}
check() {
cd "$srcdir/${pkgname%-git}"
python3 -m venv --system-site-packages --clear test-venv
source ./test-venv/bin/activate
python3 setup.py install --skip-build
python3 -m unittest discover
deactivate
}
package() {
cd "$srcdir/${pkgname%-git}"
python3 setup.py install --skip-build --root="$pkgdir"/ --optimize=1
install -Dt "$pkgdir"/usr/share/man/man1/ man/*.1
}
|