blob: 7f2512ea81238489434dc29fe206e4374fe82247 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Bastien Traverse <firstname at lastname dot email>
# Contributor: Samantha Baldwin <fuhsaz+git@cryptic.li>
# Contributor: Frederik "Freso" S. Olesen <archlinux@freso.dk>
# Contributor: Caleb Reach <jtxx000@gmail.com>
# Contributor: Felix Yan <felixonmars@gmail.com>
# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
# Contributor: Mantas Mikulėnas <grawity@gmail.com>
# Based on community/morituri and aur/morituri-git PKGBUILDs
pkgname=whipper-git
pkgver=0.4.0.r3.g71335e1
pkgrel=1
pkgdesc="A Unix CD ripper aiming for accuracy over speed -- forked from morituri"
arch=('any')
url="https://github.com/JoeLametta/whipper"
license=('GPL3')
depends=(
'accuraterip-checksum' # for accuraterip-checksum calculation
'cddb-py' # for showing but not using disc info if not in MusicBrainz (issue #28)
'cdparanoia' # for the actual ripping
'cdrdao' # for session, TOC, pregap, and ISRC extraction
'gstreamer0.10-base' # for encoding
'gstreamer0.10-base-plugins' # for appsink
'gstreamer0.10-good-plugins' # for wav encoding
'gstreamer0.10-python' # for encoding
'libsndfile' # for reading wav files (pulls in flac, also required for reading flac files)
'python2-musicbrainzngs' # for metadata lookup
'python2-pycdio' # for storing drive identification in config file
'python2-setuptools' # for plugin support
'sox' # for track peak detection'
)
makedepends=(
'git'
'python2-gobject2'
)
provides=('whipper')
conflicts=('whipper')
source=("${pkgname/-git}::git+${url}.git")
md5sums=('SKIP')
pkgver() {
cd "$srcdir/${pkgname/-git}"
# Cutting off "v" prefix present in the git tag
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/${pkgname/-git}"
git submodule init
git submodule update
}
build() {
cd "$srcdir/${pkgname/-git}"
export PYTHON=$(which python2)
python2 setup.py build
}
package() {
cd "$srcdir/${pkgname/-git}"
python2 setup.py install --root="${pkgdir}"/ --optimize=1
}
|