PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: Bruce Zhang
pkgname=wifite2
pkgver=2.2.5
pkgrel=1
pkgdesc="Rewrite of the popular wireless network auditor, \"wifite\""
arch=('x86_64' 'i686')
url="https://github.com/derv82/wifite2"
license=('GPL')
depends=('python' 'wireless_tools' 'net-tools' 'aircrack-ng')
optdepends=(
	'wireshark-cli: For detecting WPS networks and inspecting handshake capture files'
	'reaver: For WPS Pixie-Dust & brute-force attacks'
	'bully: For WPS Pixie-Dust & brute-force attacks'
	'cowpatty: For detecting handshake captures'
	'pyrit: For detecting handshake captures'
	'hashcat: For cracking PMKID hashes'
)
provides=('wifite')
conflicts=('wifite')
source=("$pkgname-$pkgver.src.tar.gz::https://github.com/derv82/wifite2/archive/$pkgver.tar.gz")
sha256sums=('3ca7c04502dd153047b71f9ffb24b2e91687a1b597b70d2c2790faebddf1b04b')

build() {
	cd "$pkgname-$pkgver"
	LANG=en_US.UTF-8 python setup.py build
}

package() {
	cd "$pkgname-$pkgver"
	LANG=en_US.UTF-8 python setup.py install --root="$pkgdir/" --optimize=1 --skip-build

	# Move sbin/wifite to bin/wifite
	mv "$pkgdir/usr/sbin" "$pkgdir/usr/bin"
}