blob: 02416e642d91d4b0d01a3bf1b08ed688104bb04a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Eric Biggers <ebiggers3 at gmail dot com>
pkgname=wimlib
pkgver=1.9.0
pkgrel=1
pkgdesc="A library and program to extract, create, and modify WIM files"
arch=("i686" "x86_64")
url="https://wimlib.net"
license=("custom")
depends=("openssl" "fuse" "libxml2" "ntfs-3g" "attr")
optdepends=("cdrkit: for making ISO image of Windows PE"
"mtools: for making disk image of Windows PE"
"syslinux: for making disk image of Windows PE"
"cabextract: for extracting Windows PE from the WAIK"
"ntfsprogs: for making NTFS filesystems")
checkdepends=("ntfsprogs")
source=("https://wimlib.net/downloads/$pkgname-$pkgver.tar.gz")
build() {
cd "$pkgname-$pkgver"
./configure --with-libcrypto --with-fuse --with-ntfs-3g --prefix=/usr
make
}
check() {
cd "$pkgname-$pkgver"
make check
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
for file in NEWS README; do
install -Dm644 $file "$pkgdir/usr/share/doc/$pkgname/$file"
done
for file in COPYING*; do
install -Dm644 $file "$pkgdir/usr/share/licenses/$pkgname/$file"
done
}
sha1sums=('b2d68a62661b254da3b0c2860110da8be68844a1')
|