blob: f818fcd8bfaec1215129690e5bdec7ad9a6b9e30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
# Maintainer: Mike Swanson <mikeonthecomputer@gmail.com>
# Warning: If you are downgrading from the development branch (Wine >= 2.1,
# for example), your WINEPREFIX may break and experience unusual bugs.
# Try to make a clean WINEPREFIX, such as by doing “rm -rf ~/.wine”
pkgname=wine-stable
pkgver=2.0.3
pkgrel=1
source=(https://dl.winehq.org/wine/source/2.0/wine-$pkgver.tar.xz{,.sign}
30-win32-aliases.conf)
sha512sums=('e20dbcb3a48ecb3526eba075d4baebab2529dfc50b7a6d5e18294704470f61db386013f457118c270274b911f9643d203110f46558d23e84e6a6c2d78e237dbb'
'SKIP'
'6e54ece7ec7022b3c9d94ad64bdf1017338da16c618966e8baf398e6f18f80f7b0576edf1d1da47ed77b96d577e4cbb2bb0156b0b11c183a0accf22654b0a2bb')
validpgpkeys=(5AC1A08B03BD7A313E0A955AF5E6E9EEB9461DD7
DA23579A74D4AD9AF9D3F945CEFAC8EAAF17519D)
pkgdesc="A compatibility layer for running Windows programs"
url="http://www.winehq.com"
arch=(i686 x86_64)
options=(staticlibs)
license=(LGPL)
depends=(desktop-file-utils fontconfig freetype2 gettext glu lcms2
libpcap libsm libxcursor libxdamage libxi libxml2 libxrandr)
depends_x86_64=(lib32-fontconfig lib32-freetype2 lib32-gcc-libs
lib32-gettext lib32-glu lib32-lcms2 lib32-libpcap lib32-libsm
lib32-libxcursor lib32-libxdamage lib32-libxi lib32-libxml2
lib32-libxrandr)
makedepends=(alsa-lib fontforge giflib gnutls libgl libldap libpng
libpulse libxcomposite libxinerama libxmu libxslt libxxf86vm mesa
mpg123 ncurses ocl-icd openal opencl-headers samba v4l-utils)
makedepends_x86_64=(gcc-multilib lib32-alsa-lib lib32-giflib
lib32-gnutls lib32-libgl lib32-libldap lib32-libpng lib32-libpulse
lib32-libxcomposite lib32-libxinerama lib32-libxmu lib32-libxslt
lib32-libxxf86vm lib32-mesa lib32-mpg123 lib32-ocl-icd lib32-openal
lib32-v4l-utils)
optdepends=(alsa-lib alsa-plugins cups dosbox giflib gnutls
libjpeg-turbo libldap libpng libpulse libxcomposite libxinerama
libxslt mpg123 ncurses ocl-icd openal samba v4l-utils)
optdepends_x86_64=(lib32-alsa-lib lib32-alsa-plugins lib32-giflib
lib32-gnutls lib32-libjpeg-turbo lib32-libldap lib32-libpng
lib32-libpulse lib32-libxcomposite lib32-libxinerama lib32-libxslt
lib32-mpg123 lib32-ncurses lib32-ocl-icd lib32-openal
lib32-v4l-utils)
provides=("wine=$pkgver")
conflicts=("wine")
prepare() {
# Allow ccache to work
mv wine-$pkgver wine
for patch in *.patch; do
if [ ! -f "$patch" ]; then
break;
else
patch -d wine -p1 -i "../$patch"
fi
done
sed 's|OpenCL/opencl.h|CL/opencl.h|g' -i wine/configure*
# Get rid of old build dirs
rm -rf wine-{32,64}-build
mkdir wine-{32,64}-build
}
build() {
cd "$srcdir"
if [[ $CARCH == x86_64 ]]; then
msg2 "Building Wine-64..."
cd "$srcdir/wine-64-build"
../wine/configure \
--prefix=/usr \
--libdir=/usr/lib \
--with-x \
--with-gstreamer \
--enable-win64
make
_wine32opts=(
--libdir=/usr/lib32
--with-wine64="$srcdir/wine-64-build"
)
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
fi
msg2 "Building Wine-32..."
cd "$srcdir/wine-32-build"
../wine/configure \
--prefix=/usr \
--with-x \
--with-gstreamer \
"${_wine32opts[@]}"
# These additional flags solve FS#23277
make CFLAGS+="-mstackrealign -mincoming-stack-boundary=2" CXXFLAGS+="-mstackrealign -mincoming-stack-boundary=2"
}
package() {
msg2 "Packaging Wine-32..."
cd "$srcdir/wine-32-build"
if [[ $CARCH == i686 ]]; then
make STRIP=true prefix="$pkgdir/usr" install
else
make STRIP=true prefix="$pkgdir/usr" \
libdir="$pkgdir/usr/lib32" \
dlldir="$pkgdir/usr/lib32/wine" install
msg2 "Packaging Wine-64..."
cd "$srcdir/wine-64-build"
make STRIP=true prefix="$pkgdir/usr" \
libdir="$pkgdir/usr/lib" \
dlldir="$pkgdir/usr/lib/wine" install
fi
# Font aliasing settings for Win32 applications
install -d "$pkgdir"/etc/fonts/conf.{avail,d}
install -m644 "$srcdir/30-win32-aliases.conf" "$pkgdir/etc/fonts/conf.avail"
ln -s ../conf.avail/30-win32-aliases.conf "$pkgdir/etc/fonts/conf.d/30-win32-aliases.conf"
}
|