summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 413b05ddf2f074d4fa62edd6467d917a99c8c324 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>

pkgname=wingpanel-git
pkgver=2.3.2.r5.ge864189
pkgrel=1
pkgdesc='Stylish top panel that holds indicators and spawns an application launcher'
arch=(x86_64)
url=https://github.com/elementary/wingpanel
license=(GPL3)
groups=(pantheon-unstable)
depends=(
  glib2
  gtk3
  libgala.so
  libgee
  libgranite.so
  mutter
)
makedepends=(
  gala-git
  git
  granite-git
  meson
  vala
)
provides=(
  libwingpanel-3.0.so
  wingpanel
)
conflicts=(wingpanel)
source=(git+https://github.com/elementary/wingpanel.git)
sha256sums=(SKIP)

pkgver() {
  cd wingpanel

   git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson wingpanel build \
    -D b_pie=false
  ninja -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
}

# vim: ts=2 sw=2 et: