blob: 676f356704046c655534d4bb2b438fc3683f8b03 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Conor Anderson <conor@conr.ca>
pkgname=wire-desktop-git
_pkgname=${pkgname%-git}
pkgver=2.17.2813.r12.g6b21ba3
pkgrel=1
pkgdesc='Modern, private messenger'
arch=('x86_64' 'i686')
url='https://wire.com/'
license=('GPL3')
conflicts=('wire-desktop-bin' 'wire-desktop')
depends=('alsa-lib' 'gconf' 'gtk2' 'libxss' 'libxtst' 'nss' 'xdg-utils')
makedepends=('cargo' 'npm' 'python2')
optdepends=('hunspell-en: for English spellcheck support')
provides=('wire-desktop')
source=("git://github.com/wireapp/wire-desktop.git"
"wire-desktop.desktop")
sha256sums=('SKIP'
'84d869ca111010a5f45f3d5cb8ef4320fa46ac01104773559fb3a7c501f8313b')
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/release\///g'
}
build() {
cd "${srcdir}/${_pkgname}"
npm install
$(npm bin)/grunt 'linux-other'
}
package() {
# Place files
install -d "${pkgdir}/usr/lib/${_pkgname}"
cp -a "${srcdir}/${_pkgname}"/wrap/dist/linux*unpacked/* "${pkgdir}/usr/lib/${_pkgname}"
# Symlink main binary
install -d "${pkgdir}/usr/bin"
ln -s "/usr/lib/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
# Place desktop entry and icon
desktop-file-install -m 644 --dir "${pkgdir}/usr/share/applications/" "${srcdir}/${_pkgname}.desktop"
for res in 32x32 256x256; do
install -dm755 "${pkgdir}/usr/share/icons/hicolor/${res}/apps"
install -Dm644 "${srcdir}/${_pkgname}/resources/icons/${res}.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}/apps/${_pkgname}.png"
done
# Spellcheck dictionaries
rm -rf "${pkgdir}/usr/lib/${_pkgname}/resources/app/node_modules/spellchecker/vendor/hunspell_dictionaries"
ln -s "/usr/share/hunspell" "${pkgdir}/usr/lib/${_pkgname}/resources/app/node_modules/spellchecker/vendor/hunspell_dictionaries"
# Place license files
for license in "LICENSE.electron.txt" "LICENSES.chromium.html"; do
install -Dm644 "${pkgdir}/usr/lib/${_pkgname}/${license}" "${pkgdir}/usr/share/licenses/${_pkgname}/${license}"
rm "${pkgdir}/usr/lib/${_pkgname}/${license}"
done
}
|