blob: b0ad7c16e9501202d18bb98620eae54d44d92282 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Conor Anderson <conor.anderson@mail.utoronto.ca>
pkgname=wire-desktop-git
_pkgname=wire-desktop
pkgver=2.11.2666.r0.g7af8437
pkgrel=1
pkgdesc='Modern communication, full privacy.'
arch=('x86_64' 'i686')
url='https://wire.com/'
license=('GPL3')
conflicts=('wire-desktop-bin' 'wire-desktop')
depends=('nss' 'alsa-lib' 'libxss' 'gconf' 'gtk2' 'libxtst')
makedepends=('npm' 'nodejs-grunt-cli' 'gendesk' 'python2')
provides=('wire-desktop')
source=("git://github.com/wireapp/wire-desktop.git"
"Gruntfile.patch")
sha256sums=(SKIP
'fc8a2d5badde0b3049df843f497a999a8cfeff05a261343d9094d3ba35ca4202')
pkgver() {
cd ${srcdir}/${_pkgname}
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/release\///g'
}
prepare() {
gendesk -f -n --name=Wire --pkgname=${_pkgname} --pkgdesc="${pkgdesc}" --exec=wire --categories="Network"
cd ${srcdir}/${_pkgname}
patch -p0 < $startdir/Gruntfile.patch
}
build() {
cd ${srcdir}/${_pkgname}
npm install
grunt linux-prod
}
package() {
# Place files
install -d ${pkgdir}/opt/${_pkgname}
if [ $CARCH == 'x86_64' ]; then
cp -a ${srcdir}/${_pkgname}/wrap/build/Wire-linux-x64/* ${pkgdir}/opt/${_pkgname}
else
cp -a ${srcdir}/${_pkgname}/wrap/build/Wire-linux-ia32/* ${pkgdir}/opt/${_pkgname}
fi
# Symlink main binary
install -d ${pkgdir}/usr/bin
ln -s "/opt/${_pkgname}/Wire" "${pkgdir}/usr/bin/wire"
# Place desktop entry and icon
install -Dm644 ${_pkgname}.desktop ${pkgdir}/usr/share/applications/${_pkgname}.desktop
install -Dm644 ${srcdir}/${_pkgname}/electron/img/wire.png ${pkgdir}/usr/share/pixmaps/${_pkgname}.png
# Place license files
install -Dm644 "${pkgdir}/opt/${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
install -Dm644 "${pkgdir}/opt/${_pkgname}/LICENSES.chromium.html" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSES.chromium.html"
rm "${pkgdir}/opt/${_pkgname}/LICENSE"
rm "${pkgdir}/opt/${_pkgname}/LICENSES.chromium.html"
}
|