blob: 9449a6ee8d5d5f302b91b8d331f4b74f00829145 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Christian Hesse <mail@eworm.de>
pkgbase=wireguard-git
pkgname=(wireguard-dkms-git wireguard-tools-git)
pkgver=0.0.20160630.r1.g9a052f6
pkgrel=1
pkgdesc='next generation secure network tunnel - git checkout'
arch=('x86_64' 'i686')
url='http://www.wireguard.io/'
license=('GPL')
makedepends=('git' 'libmnl')
source=('git+https://git.zx2c4.com/WireGuard'
'dkms.conf')
sha256sums=('SKIP'
'f34dced05d2b1d9713da12eeef02e71db213646a4c8f6852227430bd84127433')
pkgver() {
cd WireGuard/
if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
printf '%s.r%s.g%s' \
"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
"$(git rev-list --count ${GITTAG}..)" \
"$(git log -1 --format='%h')"
else
printf '0.r%s.g%s' \
"$(git rev-list --count master)" \
"$(git log -1 --format='%h')"
fi
}
build() {
cd WireGuard/src/tools/
make
}
package_wireguard-dkms-git() {
depends=('dkms')
cd WireGuard/src/
install -d -m0755 "${pkgdir}"/usr/src/wireguard-${pkgver}/crypto/
install -D -m0755 "${srcdir}"/dkms.conf "${pkgdir}"/usr/src/wireguard-${pkgver}/dkms.conf
install -m0755 Makefile *.c *.h "${pkgdir}"/usr/src/wireguard-${pkgver}/
install -m0755 crypto/* "${pkgdir}"/usr/src/wireguard-${pkgver}/crypto/
}
package_wireguard-tools-git() {
depends=('libmnl')
cd WireGuard/src/tools/
make DESTDIR="${pkgdir}/" install
}
|