blob: 3f9f8cf1c036df0091698752a30c05cbb4597a5b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Adrian Perez de Castro <aperez@igalia.com>
pkgname='wlroots-git'
pkgver=0.2.r62.ged5296c6
pkgrel=1
license=('custom:MIT')
pkgdesc='Modular Wayland compositor library'
url='https://github.com/swaywm/wlroots'
arch=('x86_64')
provides=('wlroots')
conflicts=('wlroots')
options=('debug' '!strip')
depends=('libcap' 'systemd' 'wayland' 'opengl-driver' 'libxcb'
'xcb-util-errors' 'xcb-util-image' 'xcb-util-wm' 'pixman'
'libinput' 'libxkbcommon' 'libpng' 'ffmpeg')
makedepends=('meson' 'ninja' 'git' 'wayland-protocols')
source=("${pkgname}::git+${url}")
sha512sums=('SKIP')
pkgver () {
cd "${pkgname}"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build () {
cd "${pkgname}"
rm -rf build
meson build \
--prefix /usr \
--buildtype debug \
-Dlibcap=enabled \
-Dlogind=enabled \
-Dlogind-provider=systemd \
-Dxcb-errors=enabled \
-Dxcb-icccm=enabled \
-Dxcb-xkb=enabled \
-Dxwayland=enabled \
-Dx11-backend=enabled \
-Drootston=true \
-Dexamples=true
ninja -C build
}
package () {
cd "${pkgname}"
DESTDIR="${pkgdir}" ninja -C build install
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# Manually install rootston, "ninja installs" skips it.
install -Dm755 build/rootston/rootston \
"${pkgdir}/usr/bin/rootston"
install -Dm755 rootston/rootston.ini.example \
"${pkgdir}/usr/share/doc/${pkgname}/rootston.ini.example"
}
|