blob: c43eafa4a18a37425a8cef60a3219b576aeb42db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: Antonin Décimo <antonin dot decimo at gmail dot com>
# Contributor: Adrian Perez de Castro <aperez@igalia.com>
pkgname=wlroots-hidpi-git
pkgver=0.16.0.r5511.e59f4d4f
pkgrel=1
license=(custom:MIT)
pkgdesc='Modular Wayland compositor library, with XWayland HiDPI (git version)'
url=https://gitlab.freedesktop.org/wlroots/wlroots
arch=(x86_64)
provides=("libwlroots.so" "wlroots=${pkgver%%.r*}")
conflicts=(wlroots wlroots-git)
options=(debug)
depends=(
glslang
libinput
libxcb
libxkbcommon
opengl-driver
pixman
wayland
xcb-util-errors
xcb-util-renderutil
xcb-util-wm
seatd
vulkan-icd-loader
vulkan-validation-layers
xorg-xwayland)
makedepends=(
git
meson
vulkan-headers
wayland-protocols
xorgproto)
# https://gitlab.freedesktop.org/MisterDA/wlroots/-/tree/xwayland_hidpi
source=("${pkgname}::git+${url}.git"
"0001-xwayland-add-support-for-global-scale-factor.patch"
"0002-xwayland-add-support-for-changing-global-scale-facto.patch"
)
sha256sums=('SKIP'
'2d3736475593a4644e93c839a5d19644551bb459b8a59e8c03c18dfbafeecdfc'
'89ddc2d7bece7992e9913d03144b475da3c594ff7552ac2da6b5ae4ad6ffe2eb')
_builddir="build"
_builddir_pkgver="build-pkgver"
_meson_setup () {
arch-meson \
--buildtype=debug \
-Dwerror=false \
-Dexamples=false \
"${pkgname}" "$1"
}
prepare () {
(
cd "${pkgname}"
patch -Np1 < "${srcdir}/0001-xwayland-add-support-for-global-scale-factor.patch"
patch -Np1 < "${srcdir}/0002-xwayland-add-support-for-changing-global-scale-facto.patch"
)
_meson_setup "${_builddir_pkgver}"
}
pkgver () {
(
set -o pipefail
meson introspect --projectinfo "${_builddir_pkgver}" \
| awk 'match($0, /"version":\s*"([[:digit:]]+\.[[:digit:]]+\.[[:digit:]]+)-dev"/, ret) {printf "%s",ret[1]}'
)
cd "${pkgname}"
printf ".r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build () {
_meson_setup "${_builddir}"
meson compile -C "${_builddir}"
}
package () {
DESTDIR="${pkgdir}" meson install -C build
install -Dm644 "${pkgname}/"LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
post_upgrade() {
echo "Make sure to upgrade wlroots-hidpi-git and sway-hidpi-git together."
echo "Upgrading one but not the other is unsupported."
}
|