blob: ed0dc8d450ed13751eeb803b4bb4d215ff7c4e52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Antonin Décimo <antonin dot decimo at gmail dot com>
# Contributor: Adrian Perez de Castro <aperez@igalia.com>
pkgname=wlroots-hidpi-git
pkgver=0.14.0.r303.gf7ea33da
pkgrel=1
license=(custom:MIT)
pkgdesc='Modular Wayland compositor library, with XWayland HiDPI (git version)'
url=https://github.com/swaywm/wlroots
arch=(x86_64)
provides=("libwlroots.so" "wlroots=${pkgver%%.r*}")
conflicts=(wlroots wlroots-git)
options=(debug)
depends=(
glslang
libinput
libxcb
libxkbcommon
opengl-driver
pixman
wayland
xcb-util-errors
xcb-util-renderutil
xcb-util-wm
seatd
vulkan-icd-loader
xorg-xwayland)
makedepends=(
git
meson
vulkan-headers
wayland-protocols
xorgproto)
source=("${pkgname}::git+${url}"
# "xwayland_hidpi.diff::https://github.com/swaywm/wlroots/pull/2064.diff"
"xwayland_hidpi.diff::https://github.com/swaywm/wlroots/compare/master...MisterDA:xwayland_hidpi.diff"
)
sha256sums=('SKIP'
'bd3a5295c404be332372d1504177d1e7c7fd8649b0bc9ef603c586843a46f4b4')
pkgver () {
cd "${pkgname}"
(
set -o pipefail
git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
prepare () {
cd "${pkgname}"
patch --forward --strip=1 --input="${srcdir}/xwayland_hidpi.diff"
}
build () {
arch-meson \
--buildtype=debug \
-Dwerror=false \
-Dexamples=false \
"${pkgname}" build
meson compile -C build
}
package () {
DESTDIR="${pkgdir}" meson install -C build
install -Dm644 "${pkgname}/"LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
post_upgrade() {
echo "Make sure to upgrade wlroots-hidpi-git and sway-hidpi-git together."
echo "Upgrading one but not the other is unsupported."
}
|