blob: d2e358b995c6056ba32cbf4907f2d550ab650d30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: q234 rty <q23456yuiop at gmail dot com>
# Contributor: lilydjwg <lilydjwg@gmail.com>
# Contributor: Adrian Perez de Castro <aperez@igalia.com>
# Contributor: Antonin Décimo <antonin dot decimo at gmail dot com>
pkgname=wlroots-hidpi-xprop-git
pkgver=0.16.0.20220907.140046
pkgrel=1
license=(MIT)
pkgdesc='Modular Wayland compositor library (git version, with patches)'
url=https://gitlab.freedesktop.org/wlroots/wlroots
arch=(x86_64)
provides=("libwlroots.so" "wlroots=${pkgver%%.202*}" "wlroots-git")
conflicts=(wlroots wlroots-git)
options=(debug)
depends=(
glslang
libinput
libxcb
opengl-driver
xcb-util-errors
xcb-util-renderutil
xcb-util-wm
'libpixman-1.so'
'libseat.so'
'libudev.so'
'libvulkan.so'
'libwayland-client.so'
'libwayland-server.so'
'libxkbcommon.so'
xorg-xwayland)
optdepends=('xorg-xwayland-hidpi-xprop: HiDPI support, see https://gitlab.freedesktop.org/xorg/xserver/-/merge_requests/733')
makedepends=(
git
meson
vulkan-headers
wayland-protocols
xorgproto)
source=("${pkgname}::git+${url}.git"
https://gitlab.freedesktop.org/lilydjwg/wlroots/-/commit/6c5ffcd1fee9e44780a6a8792f74ecfbe24a1ca7.patch)
sha512sums=('SKIP'
'c2193fb6d3063919ecb427a72d09fd11563a9de68e848e9721d7a7d9dc67e700654067ce154b1ddc5fb4587b9cea71d29a73a55a18f54d6ecd60897989677bb2')
pkgver () {
cd "${pkgname}"
(
set -o pipefail
version=$(grep -zoP "project\([^)]*\)" meson.build | xargs --null echo | grep -oP "^\sversion:\s'\K[^-']*")
printf "${version}.%s" "$(TZ=UTC git log -1 --pretty='%cd' --date=format-local:%Y%m%d.%H%M%S)"
)
}
prepare () {
cd "${pkgname}"
git revert -n 18595000f3a21502fd60bf213122859cc348f9af
patch -Np1 < ../6c5ffcd1fee9e44780a6a8792f74ecfbe24a1ca7.patch
}
build () {
arch-meson \
--buildtype=debug \
-Dwerror=false \
-Dexamples=false \
"${pkgname}" build
meson compile -C build
}
package () {
DESTDIR="${pkgdir}" meson install -C build
install -Dm644 "${pkgname}/"LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|