blob: 998e89e7e053f09bead19feeca57266a98ab2e86 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Frederik “Freso” S. Olesen <archlinux@freso.dk>
_pkgname=wootility
pkgname=${_pkgname}-appimage
pkgver=3.4.6
pkgrel=1
pkgdesc='Utility for configuring Wooting keyboards (binary AppImage version)'
arch=('x86_64')
url='https://wooting.io/wootility'
license=('unknown')
depends=('fuse2')
makedepends=('p7zip')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
options=(!strip)
_appimage="${_pkgname}-${pkgver}.AppImage"
install=$pkgname.install
source=("https://s3.eu-west-2.amazonaws.com/wooting-update/wootility-linux-latest/${_appimage}"
'70-wooting.rules')
noextract=("${_appimage}")
sha512sums=('0f9647e2e713b5bd049abc54d0d991f52861b907d4625a784464266f44ade96efc629fa144626656a02f6304e1a4fc38bd094e6ccbcc3c4c11ad9f761dda0342'
'3a569cb1292efc31e22fd6c425fff14ac98d7f280849b3d81cdd72523a3388e6623bcd026571f726656fb339f9b90527efd8829d82de1d0b1ac778921dd72633')
prepare() {
7z x "${_appimage}" 'wootility.desktop' 'usr/share/icons' > /dev/null
}
build() {
sed -i -E "s|Exec=AppRun|Exec=${_pkgname}|" wootility.desktop
# Fix permissions; .AppImage permissions are 700 for all directories
chmod -R a-x+rX usr
}
package() {
install -Dpm755 "${_appimage}" "${pkgdir}/opt/${_pkgname}/${_appimage}"
install -d "${pkgdir}/usr/bin"
ln -s "../../opt/${_pkgname}/${_appimage}" "${pkgdir}/usr/bin/${_pkgname}"
install -Dpm644 'wootility.desktop' "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -d "${pkgdir}/usr/share/icons"
cp -a usr/share/icons/hicolor "${pkgdir}/usr/share/icons/hicolor"
install -Dpm644 '70-wooting.rules' "${pkgdir}/usr/lib/udev/rules.d/70-wooting.rules"
}
|