blob: 89859be590c40e863b07bcc2e4d3b760e10d25ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Frederik “Freso” S. Olesen <archlinux@freso.dk>
_pkgname=wootility
pkgname=${_pkgname}-appimage
pkgver=2.5.5
pkgrel=1
pkgdesc='Utility for configuring Wooting keyboards (binary AppImage version)'
arch=('x86_64')
url='https://wooting.io/wootility'
license=('unknown')
makedepends=('p7zip')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
options=(!strip)
_appimage="${_pkgname}-${pkgver}-x86_64.AppImage"
source=("https://s3.eu-west-2.amazonaws.com/wooting-update/wootility-linux-latest/${_appimage}"
'70-wooting.rules')
noextract=("${_appimage}")
sha512sums=('e8b3eba72c6f4d827d5d9e679c4dc85530f068329046b5b1f558bef8540f89963c2deef088bef0260aae1e8d17cf18d6ebc248d3827fe0bb45b0a385cbab03c3'
'3eddcccc40a6ddc924777ced27e757f966889bf789b312ec87c7ba76e69362f14231a5559b86259eb641e5cf1d14333c23fb344a3d278870ba6843fc5dff6579')
prepare() {
7z x "${_appimage}" 'wootility.desktop' 'usr/share/icons' > /dev/null
}
build() {
sed -i -E "s|Exec=AppRun|Exec=${_pkgname}|" wootility.desktop
# .AppImage permissions are 700 for all directories
chmod -R 755 usr
chmod -x usr/share/icons/hicolor/*x*/apps/*
}
package() {
install -Dpm755 "${_appimage}" "${pkgdir}/opt/${_pkgname}/${_appimage}"
install -d "${pkgdir}/usr/bin"
ln -s "../../opt/${_pkgname}/${_appimage}" "${pkgdir}/usr/bin/${_pkgname}"
install -Dpm644 'wootility.desktop' "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
install -d "${pkgdir}/usr/share/icons"
cp -a usr/share/icons/hicolor "${pkgdir}/usr/share/icons/hicolor"
install -Dpm644 '70-wooting.rules' "${pkgdir}/usr/lib/udev/rules.d/70-wooting.rules"
}
|