blob: 5a5e3448651653aae47247933b497695fcd1a4dc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Aaron Fischer <mail@aaron-fischer.net>
# Contributor: J. W. Birdsong <jwbirdsong AT gmail DOT com>
# Contributor: Kevin Piche <kevin@archlinux.org>
pkgname=worker
pkgver=3.14.0
pkgrel=1
pkgdesc="A file manager for the X Window System"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.boomerangsworld.de/worker"
depends=('avfs' 'gcc-libs' 'libx11' 'file')
makedepends=('libxt')
source=(http://www.boomerangsworld.de/cms/${pkgname}/downloads/${pkgname}-${pkgver}.tar.bz2
http://www.boomerangsworld.de/cms/${pkgname}/downloads/${pkgname}-${pkgver}.tar.bz2.asc)
sha256sums=('192ffbee512d8a0828d33a30193f3a6de900a74556c963464762c18de566151b'
'55750c4c5c01f43cb976fe7a83ff4a33ebf67aff737ad13351cc7abfef9f4ce7')
validpgpkeys=('F9299EE90A729029E71AF26B667132D0FBC52B37') # Ralf Hoffmann
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# We need to disable the optimizations because of a bug in gcc
# (see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=63140 for details)
# Ralf added a gcc constraint check to avoid compiling bad optimized code.
# Because we run a recent version of gcc, we disable the check, and
# disable also the compiler optimizations completely. Because the code
# uses some C++11 features, we need to set this explicitly.
#
# To bypass the pthread bug, the LDFLAGS is set here explicit until
# the bug is solved. See here for more detail and progress:
# https://sourceforge.net/p/workerfm/mailman/message/34136485/
CPPFLAGS="-O0 -std=gnu++11" LDFLAGS=-pthread ./configure --enable-xft --prefix=/usr --disable-cxx-check
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|