blob: 266a95b3d10ad42f801d8db83e655735a983ad76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Hunter Peavey < vrywjvgviuotxeioqipx at disroot dot org >
# General package information
pkgname=wtwitch
pkgver=1.7.1
pkgrel=1
pkgdesc="Terminal user interface for Twitch"
url="https://git.sr.ht/~krathalan/wtwitch"
license=("GPL3")
arch=("any")
changelog="CHANGELOG"
# Dependencies
depends=("curl" "jq" "streamlink")
makedepends=("scdoc")
optdepends=('mpv: for watching streams'
'vlc: for watching streams')
# Download information
_packagesig="${url}/blob/master/signatures/${pkgver}.tar.gz.sig"
source=("${url}/archive/${pkgver}.tar.gz" "${_packagesig}")
validpgpkeys=("B46B326273E4A1D21AAA3F6F529AC10050BD24EF")
sha512sums=("c5a577da9d3c1afc8086714a1114900527132993fa9685cba156f75067b4ef532357e2a141e82f3c33421374a742ff08265c1192c89957f4aa6f19fb064760fd" "e1822e60b92250d81706ff8468f7946c232fcb282955cbe191f196f363c6b38e59664c8b47b8b8f2ede85ee76c9e1547809c2b5d860ea6b245c41d9748dc4200")
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Create man page
scdoc < wtwitch.1.scd > wtwitch.1
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
# wtwitch "binary"
install -D -m755 wtwitch "${pkgdir}/usr/bin/${pkgname}"
# man page
install -D -m644 wtwitch.1 "${pkgdir}/usr/share/man/man1/wtwitch.1"
}
|