blob: 5ca3198a3d92d894465cd9f98d497bc4653214a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# Maintainer: Andrea Zanellato <redtid3@gmail.com>
_prjname=wxcode
pkgname=${_prjname}-git
pkgver=1299.e2f5c33
pkgrel=1
pkgdesc="wxCode plugin for wxWeaver and custom wxWidgets controls library"
arch=("i686" "x86_64" "aarch64")
url="https://wxweaver.github.io"
license=("GPL2")
depends=("wxgtk3" "wxweaver")
makedepends=("git" "cmake")
source=("git+https://github.com/wxweaver/${_prjname}.git")
sha512sums=("SKIP")
pkgver() {
cd "${srcdir}/${_prjname}"
printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/${_prjname}"
git submodule update --init --recursive
}
build() {
cd "${srcdir}/${_prjname}"
mkdir -p build && cd build
cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr "${srcdir}/${_prjname}"
cmake --build .
}
package() {
cd "${srcdir}/${_prjname}"
DESTDIR="${pkgdir}" cmake --build "${srcdir}/${_prjname}/build" --target install
}
|