summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fe41aa18c956f721a36724c5549065b58a3a9aef (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Jefferson Gonzalez <jgmdev@gmail.com>
# Contributor: Blair Bonnett <blair.bonnett@gmail.com>
# Contributor: Eran Yahav <eran910@gmail.com>
# Contributor: Artyom Smirnov <smirnoffjr@gmail.com>
# Contributor: Alexander Zhuk <zhuk.a.v@gmail.com>
# Contributor: Wiadufa Chen <wiadufachen@gmail.com>

pkgname=wxformbuilder-git
_gitname=wxFormBuilder
pkgver=3.9.0.r188.g0eccdbc5
pkgrel=1
pkgdesc="Designer, GUI builder, and RAD tool For wxWidgets"
arch=('i686' 'x86_64' 'aarch64')
url="https://sourceforge.net/projects/wxformbuilder/"
license=('GPL')
provides=('wxformbuilder')
conflicts=('wxformbuilder' 'wxformbuilder-svn')
depends=('wxgtk3' 'boost')
makedepends=('git' 'ninja' 'meson')
source=(
  "git://github.com/wxFormBuilder/wxFormBuilder.git"
  "nativefile.ini"
)
md5sums=(
  'SKIP'
  '124daaf4663d8e4285a17e9e0f1f4d6a'
)

pkgver() {
  cd "${srcdir}/${_gitname}"
  git describe --tags --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/^v\([0-9]\)/\1/g'
}

prepare() {
  cd "$srcdir/${_gitname}"
  git submodule update --init
}

build() {
  cd "$srcdir/${_gitname}"
  meson setup _build --native-file "$srcdir"/nativefile.ini --prefix /usr
  ninja -j$(nproc) -C _build
}

package() {
  cd "$srcdir/${_gitname}"

  DESTDIR="${pkgdir}" ninja -C _build install

  mkdir -p "$pkgdir"/usr/share/mime/packages/
  cp -r install/linux/data/gnome/usr/share "$pkgdir"/usr
  install -m644 install/linux/debian/wxformbuilder.sharedmimeinfo "$pkgdir"/usr/share/mime/packages/wxformbuilder.xml
}