blob: 7799a341b86ba75786cef6fe30d1433107806cf7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org> -> https://github.com/FabioLolix
# Contributor: Peter Mattern <pmattern at arcor dot de>
pkgname=wxgtk-git
pkgver=3.2.0.r3.gdeffbf1623
pkgrel=1
pkgdesc="GTK+3 implementation of wxWidgets API for GUI"
arch=(x86_64)
url='https://www.wxwidgets.org'
license=('custom: wxWindows Library Licence')
depends=(gtk3 gst-plugins-bad libnotify libsecret)
makedepends=(git glu)
provides=(wxgtk3 wxgtk-common)
conflicts=(wxgtk3 wxgtk-common wxgtk2)
source=("wxwidgets::git+https://github.com/wxWidgets/wxWidgets.git#branch=3.2"
"git+https://github.com/wxWidgets/Catch.git"
"git+https://github.com/wxWidgets/pcre.git"
"git+https://github.com/wxWidgets/nanosvg")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd wxwidgets
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd wxwidgets
git config submodule.3rdparty/catch.url "${srcdir}/Catch"
git submodule update --init 3rdparty/catch
git config submodule.3rdparty/pcre.url "${srcdir}/pcre"
git submodule update --init 3rdparty/pcre
git config submodule.3rdparty/nanosvg.url "${srcdir}/nanosvg"
git submodule update --init 3rdparty/nanosvg
./autogen.sh
}
build() {
cd wxwidgets
./configure \
--prefix=/usr \
--libdir=/usr/lib \
--with-gtk=3 \
--with-opengl \
--enable-unicode \
--enable-graphics_ctx \
--enable-mediactrl \
--enable-webview \
--with-regex=builtin \
--with-libpng=sys \
--with-libxpm=sys \
--with-libjpeg=sys \
--with-libtiff=sys \
--disable-precomp-headers
make
make -C locale allmo
}
package() {
cd wxwidgets
make DESTDIR="$pkgdir" install
install -D -m644 docs/licence.txt $pkgdir/usr/share/licenses/$pkgname/LICENSE
}
|