blob: 7a79e5f2760202ec24b88f910010b9f38068eb7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer : Daniel Bermond < gmail-com: danielbermond >
# NOTE:
# 10-bit depth currently fails to build
# https://github.com/pkuvcl/xavs2/issues/9
pkgname=xavs2
pkgver=1.2
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='Open-Source encoder of AVS2-P2/IEEE1857.4 video coding standard'
url='https://github.com/pkuvcl/xavs2/'
license=('GPL')
depends=('glibc' 'liblsmash.so')
makedepends=('gcc7' 'yasm' 'l-smash')
provides=('libxavs2')
conflicts=('libxavs2')
replaces=('libxavs2')
source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/pkuvcl/${pkgname}/archive/${pkgver}.tar.gz")
sha256sums=('8b985aeb4d5f60b5d8bc9a5e3897f2f4c5ed6546d48f06f87828ee12f6125a5f')
prepare() {
cd "${pkgname}-${pkgver}"
# use gcc7 (it does not build with gcc8)
sed -i 's/gcc/gcc-7/' build/linux/configure
}
build() {
cd "${pkgname}-${pkgver}/build/linux"
./configure \
--prefix='/usr' \
--enable-shared \
--bit-depth='8' \
--chroma-format='all' \
--enable-lto \
--enable-pic \
--disable-swscale \
--disable-lavf \
--disable-ffms \
--disable-gpac
make
}
package() {
make -C "${pkgname}-${pkgver}/build/linux" DESTDIR="$pkgdir" install-cli install-lib-shared
}
|