blob: 7b3fb3309d5ae30cacf3416248d50652180cf60e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Lubosz Sarnecki <lubosz@gmail.com>
# Original Package: Vítor Ferreira <vitor.dominor@gmail.com>
pkgname=xboxdrv-git
pkgver=0.9.0.1412.a99985e
pkgrel=1
pkgdesc="An XBox/XBox 360 gamepad driver - as alternative to the xpad-kernel module - with more configurability, runs in userspace and supports a multitude of controllers"
arch=('i686' 'x86_64')
url="http://pingus.seul.org/~grumbel/xboxdrv/"
license=('GPL3')
depends=('libx11' 'dbus-glib' 'libusbx')
makedepends=('git' 'scons' 'boost' 'pkg-config' 'libx11' 'dbus-glib' 'libusb')
provides=('xboxdrv='$pkgver)
conflicts=('xboxdrv')
source=("${pkgname}::git://github.com/Grumbel/xboxdrv.git"
"xboxdrv.service"
"xboxdrv.conf")
md5sums=('SKIP'
'c44dc13f6d34cd7fc61c87ecd8c3a547'
'c73bb9cf8ff763e7c477366472d19813')
pkgver() {
cd ${srcdir}/${pkgname}
ver=$(cat VERSION)
revision=$(git rev-list --count HEAD)
hash=$(git log --pretty=format:'%h' -n 1)
echo $ver.$revision.$hash
}
build() {
cd ${srcdir}/${pkgname}
make PREFIX=/usr
}
package() {
cd ${srcdir}/${pkgname}
make PREFIX=/usr DESTDIR="$pkgdir/" install
install -D -m755 "$srcdir/xboxdrv.service" "$pkgdir/usr/lib/systemd/system/xboxdrv.service"
install -D -m644 "$srcdir/xboxdrv.conf" "$pkgdir/etc/conf.d/xboxdrv"
}
# vim:set ts=2 sw=2 et:
|