blob: 5ca6ebca03446d76eda0fac5076c800d3a188ca0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Brian Bidulock <bidulock@openss7.org>
pkgname=xde-ctools-git
pkgver=1.14.r16.gbeec2ee
pkgrel=1
pkgdesc="X Desktop Environment C-language tools"
groups=('xde-git')
arch=('i686' 'x86_64')
url="https://github.com/bbidulock/xde-ctools"
license=('GPL')
provides=('xde-ctools')
conflicts=('xde-ctools')
depends=('libxss' 'libwnck+-git' 'libcanberra')
makedepends=('dbus-glib' 'libunique' 'git' 'xorgproto' 'libnotify' 'gdk-pixbuf-xlib')
optdepends=('xdg-launch-git: launch with recent update and launch notification')
source=("$pkgname::git+https://github.com/bbidulock/xde-ctools.git")
md5sums=('SKIP')
pkgver() {
cd $pkgname
git describe --long --tags | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd $pkgname
./autogen.sh
}
build() {
cd $pkgname
# gtk2 is using deprecated glib2 declarations
./configure CFLAGS="-Wno-deprecated-declarations $CFLAGS"
# Fight unused direct deps
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make CFLAGS="-Wno-deprecated-declarations $CFLAGS"
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|