blob: bcbe7448d557704aa4a2151c78534f19249179bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Eric Engestrom <aur@engestrom.ch>
_TARBALL_PKGVER=1.1.0-2
_UPLOAD_YEAR=2021
_UPLOAD_MONTH=10
pkgname=xencelabs
pkgver=${_TARBALL_PKGVER/-/.}
pkgrel=1
#FIXME: find somewhere where they have a better description than in their .desktop file
pkgdesc='Driver for the Xencelabs Pen Tablets'
arch=(x86_64)
url='https://www.xencelabs.com'
license=(LGPL3)
depends=(qt5-base qt5-x11extras icu)
install=$pkgname.install
source_x86_64=("$url/wp-content/uploads/$_UPLOAD_YEAR/$_UPLOAD_MONTH/Linux-$_TARBALL_PKGVER-driver.zip")
sha256sums_x86_64=('7063c441cd594f7200f6a14c25505f25c1a129749a017478b802915f8df1b226')
prepare() {
rm -rf $pkgname-$_TARBALL_PKGVER.$CARCH
tar xf $pkgname-$_TARBALL_PKGVER.$CARCH.tar.gz
}
build() {
cd $pkgname-$_TARBALL_PKGVER.$CARCH/App
# provided by the `licenses` package
rm usr/lib/xencelabs/LGPL
# fix FSH to match Arch's
mv lib/*/ usr/lib/
rmdir lib
# Replace xencelabs.desktop copy with symlink
ln -sf ../../../usr/share/applications/xencelabs.desktop \
etc/xdg/autostart/xencelabs.desktop
# provided by package dependencies
rm usr/lib/xencelabs/lib/libQt5*
rm usr/lib/xencelabs/platforms/libqxcb.so
rm usr/lib/xencelabs/lib/libicu*
# make sure it's empty, so that if some other lib is added in a future
# release we notice it right away.
rmdir usr/lib/xencelabs/lib/
rmdir usr/lib/xencelabs/platforms/
# Now that we use the sytem libs, the wrapper doesn't do anything anymore
mkdir usr/bin
mv usr/lib/xencelabs/xencelabs usr/bin/xencelabs
rm usr/lib/xencelabs/xencelabs.sh
sed s,/usr/lib/xencelabs/xencelabs.sh,xencelabs,g -i \
usr/share/applications/xencelabs.desktop
}
package() {
cp -r --no-preserve=ownership,mode $pkgname-$_TARBALL_PKGVER.$CARCH/App/* "$pkgdir"
chmod +x "$pkgdir"/usr/bin/xencelabs
}
|