blob: 880be69d6136ad0803c4b6ec122c9757401c05d5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 281731 2016-11-21 12:14:44Z lcarlier $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=xf86-video-trident
pkgver=1.3.7
pkgrel=3
pkgdesc="X.org Trident video driver"
arch=(i686 x86_64)
url="https://xorg.freedesktop.org/"
license=('custom')
depends=('glibc')
makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=23' 'xf86dgaproto')
conflicts=('xorg-server<1.19' 'X-ABI-VIDEODRV_VERSION<23' 'X-ABI-VIDEODRV_VERSION>=24')
groups=('xorg-drivers')
source=(${url}/releases/individual/driver/${pkgname}-${pkgver}.tar.bz2{,.sig}
git-fixes.patch)
sha256sums=('ecd518de627a0d49e17c158bfc72ab657386c6907c91ef89fa09332558e413ae'
'SKIP'
'22571bf377e0cd37a8bd48e4d382f1d43010e1bde6382862c226052019120335')
validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # Matt Turner <mattst88@gmail.com>
prepare() {
cd ${pkgname}-${pkgver}
patch -Np1 -i ../git-fixes.patch
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|