blob: aa48a8367327112f92dfd94cc842e20c9ca6346c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: twa022 <twa022 at gmail dot com>
_pkgname=xfce4-settings
pkgname=${_pkgname}-devel
pkgver=4.19.1
pkgrel=1
pkgdesc="Settings manager for xfce"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://docs.xfce.org/xfce/xfce4-settings/start"
license=('GPL2')
groups=('xfce4-devel')
depends=('exo' 'libxfce4util' 'garcon' 'libxfce4ui' 'xfconf' 'libnotify' 'colord'
'libxklavier' 'adwaita-icon-theme' 'gnome-themes-extra' 'python')
optdepends=('libcanberra: for sound control')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
source=("https://archive.xfce.org/src/xfce/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.bz2"
'enable-antialias-by-default.patch')
sha256sums=('4e76008fdfeacc32c536d17c63d067889b1fc1f287f8dbb0bd4dd6710fd9aace'
'25176aa463740d344c194d94771b7bfd9550809fd2ecd0e86acceb925afcf1ac')
prepare() {
cd "${_pkgname}-${pkgver}"
# Enable font hinting by default
patch -uNp2 -r- -i ../enable-antialias-by-default.patch
}
build() {
cd "${_pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--enable-xrandr \
--enable-xcursor \
--enable-libnotify \
--enable-libxklavier \
--enable-pluggable-dialogs \
--enable-sound-settings \
--disable-debug
make
}
package() {
cd "${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|