blob: 238cc503aa8d9eb64b583f560c9d65ad6cfefd70 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: twa022 <twa022 at gmail dot com>
_pkgname=xfdesktop
pkgname=${_pkgname}-git
pkgver=4.14.0+150+g044d5dc5
pkgrel=1
pkgdesc="A desktop manager for Xfce (git version)"
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url="http://www.xfce.org/"
license=('GPL2')
groups=('xfce4')
depends=('libxfce4ui>=4.13.0' 'garcon>=0.6.0' 'hicolor-icon-theme' 'libwnck3' 'thunar')
makedepends=('intltool' 'git' 'xfce4-dev-tools')
conflicts=('xfce4-menueditor' "${_pkgname}")
provides=("${_pkgname}=${pkgver%%+*}")
replaces=('xfce4-menueditor')
options=('!libtool')
source=("${_pkgname}::git+https://gitlab.xfce.org/xfce/${_pkgname}")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
git describe --long --tags | sed -r "s:^${_pkgname}.::;s/^v//;s/^xfce-//;s/-/+/g"
}
build() {
cd "${srcdir}/${_pkgname}"
./autogen.sh \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib \
--localstatedir=/var \
--disable-static \
--enable-notifications \
--disable-debug
make
}
package() {
cd "${srcdir}/${_pkgname}"
make DESTDIR="$pkgdir" install
}
|