PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: twa022 <twa022 at gmail dot com>

_pkgname=xfwl4
pkgname=${_pkgname}-git
epoch=1
pkgver=4.21.0+148+g900b872
pkgrel=1
pkgdesc="Wayland compositor for xfce4 (git checkout)"
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url="https://gitlab.xfce.org/xfce/xfwl4"
license=('GPL-3.0-or-later')
groups=('xfce4-git')
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver%%+*}")
depends=('gtk3' 'xfconf>=4.21.2' 'libxfce4ui>=4.21.8' 'libdisplay-info' 'libdrm' 'libinput' 'mesa' 'pixman'
         'seatd' 'libxkbcommon' 'xorg-xwayland')
# Runtime only
depends+=('xfwm4'
          'xfce4-settings>=4.21.2'
          'xfdesktop>=4.21.0'
          'libxfce4windowing>=4.20.6+18+g38e4af2')
makedepends=('cargo' 'rust' 'git' 'meson' 'gettext')
source=("${_pkgname}::git+${url}")
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  git describe --long --tags | sed -r "s:^${_pkgname}.::;s/^v//;s/^xfce-//;s/-/+/g"
}

prepare() {
  cd ${_pkgname}
  
  git submodule init
  git submodule update
}

build() {
  local meson_options=(
    -Duse-system-gettext=true
  )

  arch-meson "${_pkgname}" build "${meson_options[@]}"
  meson compile -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
}